Frühlingszeit, Vogelbrutzeit! D.h. überall zwitschert es und gefiederte Tiere bekommen den Drang, sich zu paaren und dann geeignete Orte zur Eiablage zu finden. Und die Biester sind anspruchsvoll! Die brüten nicht einfach irgendwo, sondern haben sehr genaue Vorstellungen über Größe, Höhe und Geometrie des Nistplatzes. Sogar der Durchmesser des Einfluglochs spielt eine Rolle – so bevorzugt die Blaumeise Löcher von 26-28mm, während eine Kohlmeise nur einzieht, wenn die Haustür 32-34mm misst. Und da wundert man sich über das Vogelsterben, wenn die Viecher so wählerisch sind...

Wir bauen ein Vogelheim

Und so helfen Vogelliebhaber landauf, landab, dass diese heiklen Wesen geeignete Plätze finden und bauen fleißig Nistkästen. Der Bund Naturschutz hat sogar eine längliche Tabelle im Angebot, aus der man die gewünschten Bedingungen nach Vogelart ablesen kann.

Nun ist ein Nistkasten kein anspruchsvolles Projekt und stellt in der Tat oft das Einstiegsprojekt für angehende Jungheimwerker dar. Ein paar Brettchen, eine Säge und ein paar Nägel oder Schrauben und schon ist die Konstruktion bezugsfertig. Doch wer die Bedürfnisse der gefiederten Mieter ernst nimmt kommt schließlich an den Punkt an dem das Einflugloch gebohrt wird und stellt dann indigniert fest, dass kein 32mm Forstnerbohrer im Haus ist und auch das Lochsägeset die von Vögeln favorisierten schrägen Maße ohne Vorwarnung auslässt!

Moderne Probleme erfordern moderne Lösungen!

Aber einen echten Maker schreckt das nicht, denn wozu besitzt man denn den 3D-Drucker!?! Und schon haben wir einen guten Plan: Das Loch wird in einem übergroßen Standardmaß gebohrt – z.B 35, 40 der 50mm. Und dann kommt ein Adapterring rein, der genau den gewünschten Innendurchmesser hat. Perfekt! Und so kann ich exakt die Wünsche der Blaumeise umsetzen und falls diese die Miete nicht pünktlich zahlt, oder Plastik in die Biomülltonne stopft, dann ändere ich im nächsten Jahr den Durchmesser auf Gartenrotschwanz und hoffe, dass der ein besserer Mieter ist.

Also frisch ans Werk und einen Einfluglochadapter konstruieren! Ich nehme für sowas gerne Openscad – das ist kein interaktives CAD-Programm, sondern eine simple Programmiersprache in der man 3D-Modelle erzeugen kann. Das ist vielleicht nicht ideal, um eine Brücke, oder eine ganze Turbine zu entwerfen, aber es ist super, wenn man Bauteile konstruieren möchte, deren Maße konfigurierbar sein sollen. Parametrische Modelle also. Und genau das haben wir ja vor.

Der Adapter ist im Grunde simpel und besteht aus wenigen Elementen:

• Ein Zylinder
• Ein zylindrisches Loch
• Ein Ring, damit das Ganze nicht ganz durchrutschen kann

Und damit das ganze schön fest sitzt habe ich ihm noch drei dünne Rippen spendiert, die etwas vorstehen. Und für besonders anspruchsvolles Federvieh habe ich noch die Möglichkeit vorgesehen, elliptische Löcher zu machen.

In Openscad kann man solche geometrischen Elemente super leicht erzeugen, modifizieren und kombinieren. Und das sieht dann so aus:

// Nistkasteneinfluglochadapterring
// für perfekte runde, oder ovale Einfluglöcher
//
// v0.1, 2021-04-18 
// Phil


main(od=35, id1=28, id2=28, l=20, rh=2, rw=5, pr=0.7);

///////////////////////////////////////////////////////////

module main (od, id1, id2, l, rh, rw, pr) {
    // od  : outer diameter
    // id1 : inner diameter 1
    // id2 : inner diameter 2
    // l   : length
    // rh  : rim hight
    // rw  : rim width
    // pr  : press fit ridge height

    // increase rendering resolution
    $fs = $fs * 0.01;
    $fa = 1;

    difference(){
        plug(od, l, rh, rw, pr);
        bore(l, id1, id2);
    }
}

module plug(od, l, rh, rw, pr) {
    cylinder(h=l, d=od);     // outer
    cylinder(h=rh, d=od+2*rw); // rim

    // press fit ridges
    translate([od/2,0,0])
        cylinder(d=2*pr, h=l);
    rotate(a=[0,0,120]) {
        translate([od/2,0,0])
            cylinder(d=2*pr, h=l);
    }
    rotate(a=[0,0,-120]) {
        translate([od/2,0,0])
            cylinder(d=2*pr, h=l);
    }
}

module bore(l, id1, id2) {
    translate([0,0,-1]) {
        linear_extrude(height=l+2){
            resize([id1, id2])circle();
        }
    }
}

Sieht doch schon ganz brauchbar aus. Also den 3D-Drucker anwärmen, Modell rendern und slicen und das G-Code File in den Drucker laden. Sehr schön – es gibt doch nichts schöneres, als das beruhigende Surren meines Ultimakers.

Und wenn das ganze ein Geschenk sein soll, dann druckt man gleich zwei verschiedene Größen und legt den Source Code bei. Und dann sieht das so aus:

Da kann der moderne Vogel nun wirklich nichts mehr auszusetzen haben!